10 REM COPYRIGHT 1990, COMPUTE PUBLICATIONS INT'L, LTD. ALL RIGHTS RESERVED
20 POKE55,192:POKE56,91
30 IFA=0THENA=1:LOAD"FITTER.ML",8,1
40 SYS49252:REM INIT
50 POKE53280,0:POKE53281,0
60 PRINT"[147][154]TEXT FITTER - MARK TEXT LIMIT LINES[159]"
70 PRINT"SELECT CURSOR: [R]=RED [G]=GREEN"
80 PRINT"MOVE SELECTED CURSOR WITH [CRSR] KEYS"
90 PRINT"[M]=MARK LINE BETWEEN CURSORS"
100 PRINT"[U]=UNMARK LINE"
110 PRINT"[CLR]=REMOVE ALL LINES"
120 PRINT"[_]=RETURN TO THIS SCREEN"
130 PRINT"[155]PRESS [T] AT THIS SCREEN TO BEGIN"
140 PRINT"PLACING TEXT. [153]PRESS ANY OTHER KEY TO"
150 PRINT"CONTINUE MARKING LINES."
160 GETK$:IFK$=""THEN160
170 IFK$="T"THEN200
180 SYS50450:REM MARKL
190 GOTO160
200 PRINT"[147][154]TEXT FITTER - PLACE TEXT[159]"
210 PRINT"INSERT DISK AND ENTER FILENAME"
220 PRINT"(PRESS [RETURN] ALONE TO GO BACK.)"
230 SF$="":INPUTSF$:IFSF$=""THEN60
240 PRINT"ENTER FILENAME FOR LEFTOVER TEXT"
250 PRINT"(PRESS [RETURN] ALONE FOR NO FILE.)"
260 LF$="":INPUTLF$
270 OPEN2,8,2,"0:"+SF$+",S,R"
280 PRINT"[147][154]TEXT FITTER - PLACE TEXT[159]"
290 PRINT"MOVE CURSOR WITH [CRSR] KEYS"
300 PRINT"[T]=FILL WITH TEXT AT CURSOR LOCATION"
310 PRINT"[_]=RETURN TO THIS SCREEN."
320 PRINT"[155]PRESS [S] AT THIS SCREEN TO SAVE OR"
330 PRINT"PRINT THE PAGE, [F] TO START A NEW"
340 PRINT"SOURCE FILE. [153]PRESS ANY OTHER KEY TO"
350 PRINT"CONTINUE PLACING TEXT."
360 GETK$:IFK$=""THEN360
370 IFK$="S"ORK$="F"THEN420
380 SYS50683:IFPEEK(49249)=0THEN360:REM MARKTX, SAVEST
390 CLOSE2:PRINT"[147]END OF ";SF$:PRINT"PRESS ANY KEY"
400 GETK$:IFK$=""THEN400
410 GOTO200
420 IFLF$<>""THENOPEN3,8,3,"0:"+LF$+",S,W":SYS51153:CLOSE3:REM LFTOVR
430 CLOSE2
440 IFK$="F"THEN200
450 PRINT"[147][154]TEXT FITTER - SAVE/PRINT[159]"
460 PRINT"[D]=SAVE TO DISK."
470 PRINT"[P]=PRINT (BE SURE PRINTER IS READY)."
480 PRINT"[X]=EXIT."
490 GETK$:IFK$<>"D"THEN530
500 INPUT"FILENAME";SF$
510 OPEN2,8,2,"0:"+SF$+",S,W"
520 SYS51098:CLOSE2:GOTO450:REM OUTPGE
530 IFK$<>"P"THEN560
540 REM POKE51133,13:REM TO ADD RETURN TO EACH LINE
550 OPEN2,4,7:SYS51098:PRINT#2:CLOSE2:GOTO450:REM OUTPGE
560 IFK$<>"X"THEN490
570 END